In response to a suggestion in this thread I wrote a vbscript program that can be used send a command to the BOINC client to report completed WUs and then display the Windows shutdown dialog with the option of selecting; Log off, Restart, Cancel, etc.

Overview:
The script will post an update Command to BOINC for each attached project and then run the windows Shutdown dialog to select the action you want to take. It does not close the BOINC client and will not shutdown, restart, etc, Windows unless you select the action.

If anyone is interested in trying/using the script instructions for installation and the script code are included in this thread. If you would like a copy of the script in a text file email me: 3times7plus at gmail dot com and I'll send it to you.

Language: VBScript (installed with Windows since XP)
OS: Windows XP, Vista and/or 7
Tested under: WinXP Pro SP3 32 & 64, Vista Ultimate SP2 64, Win 7 Pro 32 & 64
Tested with BOINC versions 6.2.28 & 6.10.58

Please post any comments, questions and or problems to this thread.

Bill P
-------------

Installation:
1) Open a new Notepad document

2) Copy the Script (from the '**Script Start** to the '**Script End** lines in this thread

3) Paste the copied Script into the new Notepad document

4) In Notepad click File->Save As and save the file to a folder of your choice with a name of your choice and with the file type .vbs
The default Save as Type will be Text Documents (*.txt)
Select All Types (*.*) and add the .vbs extension
ex. c:\MyStuff\BoincRptSD.vbs

5) Locate the BOINC program (not data) folder.
The default directory is c:\Program Files\BOINC or c:\Program Files (x86)\BOINC
An easy way to locate it is to search the C: drive for boinccmd.exe which will be in the program directory

6) Verify the installation by:
A) Open a Command Prompt window (Start->Run->cmd.exe)
B) In the Command Prompt window enter:
Cscript //nologo "the_full_path_to_the_vbs_file_you_saved_in_step_4" /P:"BOINC_Pgm_Path" /V
ex. Cscript //nologo "c:\MyStuff\BoincRptSD.vbs" /P:"c:\Program Files\BOINC" /V
C) Press Enter

You should see something like this displayed:
Starting BoincRptSD.vbs 12/11/2010 12:12:22 PM
Profiling BOINC Project(s)
Found: 1 Project(s)
Requesting http://www.worldcommunitygrid.org/ update
Waiting for BOINC to report Results
Sleeping for 11 seconds
Ended BoincRptSD.vbs 12/11/2010 12:12:22 PM

And then a Windows Shutdown dialog window will open. Click Cancel to close it.

If there is an error message and Help lines displayed correct the error and try again.
Once it successfully runs open the BOINC messages tab and verify a User Update was requested.

A important point to remember is that if either folder or the vbs file name contains
a space you have to put double quotes around it, as in the example above.

After installation and verification you can add the script to your Start menu.

1) Create a new shortcut on your Desktop (right-click on the Desktop and select New->Shortcut

2) In the "Type the location of the item:" box enter the exact same thing you entered
in the Command Prompt during verification without the /V.
ex. Cscript //nologo "c:\MyStuff\BoincRptSD.vbs" /P:"c:\Program Files\BOINC"

3) Click Next, Name the sortcut and click Finish

4) Verify the shortcut is correct by double clicking the shortcut. An empty Command Prompt window will open.
If there is anything in it the location data you entered is incorrect.

If the Command Prompt is blank it will take about 12 seconds and then the Command Prompt will close
and the Windows Shutdown dialog box will open. Select Cancel.

5) To add it to the standard Windows Start Menu: Right click the Desktop icon and select "Pin to Start Menu"

To add it to the Classic Start Menu:
Right click the Desctop Icon and click Properties then copy the Target data from the shortcut
Close the shortcut Properties window
Right click the Start button and click Properties
In the Start Menu tab click the Classic Start menu Customize.. button
Click the Add... button
Paste the data you copied from the shortcut into the Location box and click next
Select "Programs" from the Start Menu tree and click Next
Give it a name and click Finish
Click OK twice

6) After it has been added you can delete the shortcut from the Desktop

'**Script Start**
'Author: Bill Plachy
'Version: 1.0.0
'Date: 12/11/2010

'Use: Cscript //Nologo xxx.vbs /P:["]Boinccmd_Pgm_Path["] [/V] [/H]

' /P: (Required) Is the full path to the boinccmd.exe directory/folder
' Use "" before and after if path contains spaces

' /V [Optional] Verbose (shows status messages)
' Default is Quiet (do not show status messages)

' /H [Optional] This display!

Const coSleepTime = 11000 'Time for BOINC to Update (In Milli-Seconds)
Const coGetMstrURLCmd = " --get_project_status | find /I """ 'Get Project Status Command
Const coProjCmd = " --project " 'Project Action Command
Const coUpdOp = " update" 'Update Operation
Const coMstrURL = "master URL:" 'Master URL(s) Search and Filter
Const coProjWd = " Project(s)"

If Not DoParms(boVerbose, stBCPath) Then 'Argument Error
Wscript.quit 'End Now
Else 'Show Status if Requested
call ShowStatus(boVerbose, "Starting " & Wscript.ScriptName & " " & _
FormatDateTime(Now(), VBShortDate) & " " & _
FormatDateTime(Now(), VBLongTime) & vbcrlf & _
"Profiling BOINC" & coProjWd) 'Display Status
End If

Set WshShell = CreateObject("WScript.Shell") 'Set WScript Shell
inNbURLs = -1 'Init Master URL Count

Set objExec = WshShell.Exec("%ComSpec% /C " & _
stBCPath & coGetMstrURLCmd & coMstrURL & """") 'Get Master URL List

Do While Not objExec.StdOut.AtEndOfStream 'Read All StdOut Lines
stSOLine = objExec.StdOut.ReadLine 'Get Line Value
t = InStr(1, stSOLine, coMstrURL, vbTextCompare) 'Look for Master URL Target in Text

if t > 0 then 'Found it
inNbURLs = inNbURLs + 1 'Increment Nbr Found
ReDim Preserve stURLList(inNbURLs) 'Reserve Additional Storage

stURLList(inNbURLs) = _
Trim(Right(stSOLine, Len(stSOLine) - (Len(coMstrURL) + t))) 'Store for Update
End If
Loop

call ShowStatus(boVerbose, "Found: " & _
inNbURLs + 1 & coProjWd) 'Show Number Projects Found

if inNbURLs > -1 then 'Found Active Prjects
For i = 0 To inNbURLs Step 1 'Request Project Update For All Projects
call ShowStatus(boVerbose, "Requesting " & _
stURLList(i) & coUpdOp) 'Document Status

WshShell.Exec (stBCPath & coProjCmd & _
stURLList(i) & coUpdOp) 'Issue Update Command
Next

'Give BOINC Time to Complete
If Wscript.Version > 5 Then 'WSH Version Supports Sleep
call ShowStatus(boVerbose, "Waiting for BOINC to report Results" & vbcrlf & _
"Sleeping for " & coSleepTime / 1000 & " seconds") 'Document Sleep

Wscript.Sleep coSleepTime 'Wait xx Seconds
End If
End If

call ShowStatus(boVerbose, "Ended " & Wscript.ScriptName & " " & _
FormatDateTime(Now(), VBShortDate) & " " & _
FormatDateTime(Now(), VBLongTime)) 'Doc End Time

Set objExec = Nothing 'Release WshShell.Exec Storage
Set WshShell = Nothing 'Release WshShell Storage

Set WshShell = CreateObject("Shell.Application") 'Init Shell Object
WshShell.ShutdownWindows 'Start Shutdown Dialog
Set WshShell = Nothing 'Release Shell Object Storage

Function DoParms(boVerbose, stBCPath)
Const coBCPgm = "boinccmd.exe" 'Boinccmd.exe File

'Initlize Parm Defaults
Set objArgs = Wscript.Arguments 'Init Argument Object
boVerbose = False 'Default is Quiet
stWkPath = "" 'Clear boinccmd.exe Path Build
stErrMsg = "" 'Clear Additional Error Message

'Validate Parms
If objArgs.Unnamed.Count > 0 then 'Incorrect Parm Format
DoParms = False 'Show Help and End
stErrMsg = "Arguments are incorrect" 'Set Add'l Message
elseIf objArgs.Named.Count = 0 Then 'No Parms Used
DoParms = False 'Show Help and End
Else 'Some Named Parms Passed
DoParms = True 'Default is Don't Show Help

For i = 0 To objArgs.Count - 1 Step 1 'Validate Each Parm
t = InStr(1, objArgs.Item(i), ":", vbTextCompare) 'Find End of "Name"

If t > 0 Then 'Name + Value
stParmNme = Mid(objArgs.Item(i), 2, t - 2) 'Set Parm Name Compare
Else 'Name Only
stParmNme = Mid(objArgs.Item(i), 2, 1) 'Set Parm Name Compare
End If

'/*-------------------------*/
'/* Store Argument Value */
'/*-------------------------*/
Select Case UCase(Left(stParmNme, 1)) 'First Character of Name
Case "H" 'Wants Help
DoParms = False 'Show Help and End

Case "P" 'Boinccmd.exe Path
stParmVal = Right(objArgs.Item(i), _
Len(objArgs.Item(i)) - t) 'Isolate Path Value
t = InStrRev(stParmVal, _
Left(coBCPgm, InStr(1, coBCPgm, ".", vbTextCompare) - 1), _
-1, vbTextCompare) 'See if Pgm Included

if t = 0 then 'Not Included
t = Len(stParmVal) 'End of Value
else 'Included
t = t - 1 'End of Path
end if

If Mid(stParmVal, t, 1) = "\" Then 'Has Backslash
stWkPath = Left(stParmVal, t) 'Use as Supplied
Else 'Needs Backslash
stWkPath = Left(stParmVal, t) & "\" 'Append One
End if

Case "V" 'Verbose Display
boVerbose = True 'Set True

Case Else 'Unknown Parm
stErrMsg = "Unknown Argument: " & objArgs.Item(i) 'Set Add'l Message
DoParms = False 'Show Help and End
End Select
Next
End If

If DoParms Then 'Not Requesting Help or Error Found
If Len(stWkPath) = 0 Then 'If BOINC Path Not Specified
stErrMsg = "Path to " & coBCPgm & " missing" 'Set Add'l Message
DoParms = False 'Show Help and End
else 'Specified - Validate
Set objFSO = CreateObject("Scripting.FileSystemObject") 'Init File System Object

If Not objFSO.FolderExists(stWkPath) Then 'Folder Doesn't Exist
stErrMsg = stWkPath & " Doesn't exist" 'Set Error Message
DoParms = False 'Show Help and End
elseif not objFSO.FileExists(stWkPath & coBCPgm) then 'File Doesn't Exist
stErrMsg = coBCPgm & " not found in " & stWkPath 'Set Error Message
DoParms = False 'Show Help and End
End If

Set objFSO = Nothing 'Release File System Object Storage
stBCPath = stWkPath & coBCPgm 'Return Full Boinccmd.exe Path
End If
End If

If Not DoParms Then 'Error or Help Requested
Call ShowHelp(stErrMsg) 'Show Help
End If
End Function

Sub ShowHelp(ErrMsg)
Const coVersion = "BoincRpt V1.0.0" 'This Script Version

If Len(ErrMsg) > 0 Then 'Error Message to Display
Wscript.Echo vbcrlf & "Error: " & ErrMsg & vbcrlf 'Display Error TextText
End If

Wscript.Echo coVersion & vbcrlf & vbcrlf & _
"Use: Cscript //Nologo " & Wscript.ScriptName & _
" /P:[""]Boinccmd_Pgm_Path[""] [/V] [/H]" & vbcrlf & _
" /P: (Required) Is the full path to the boinccmd.exe directory/folder" & vbcrlf & _
" Use "" before and after if path contains spaces" & vbcrlf & vbcrlf & _
" /V [Optional] Verbose (shows status messages)" & vbcrlf & _
" Default is Quiet (do not show status messages)" & vbcrlf & vbcrlf & _
" /H [Optional] This display!"
End Sub

Sub ShowStatus(boVerbose, stStatMsg)
if boVerbose then 'Displaying Status Messages
Wscript.Echo stStatMsg 'Display Status Message
End if
End Sub
'**Script End**